COMMENT ⊗   VALID 00005 PAGES
C REC  PAGE   DESCRIPTION
C00001 00001
C00002 00002	(*$NOMAIN	Routines to free up an AL program when we're done with it *)
C00031 00003	(* External routines from elsewhere *)
C00032 00004	(* auxiliary routines: freStrng, freeVaridef, freeToken, freeNode, freeIds *)
C00039 00005	(* routine to free up a program once we're done with it: freeStatement *)
C00045 ENDMK
C⊗;
(*$NOMAIN	Routines to free up an AL program when we're done with it *)

(* definition of record types & global variables used by AL *)

const 

  maxLines = 28;
  maxPPLines = 18;
  maxBpts = 25;
  maxTBpts = 20;	(* max could be exceeded by huge case stmnt *)
  listinglength = 2000;	(* Length of Listingarray *)

type

(* random type declarations for OMSI/SAIL compatibility *)

 ascii = char;
 atext = text;
 byte = 0..255;	

(* Here are all the pointer-type definitions.  Since the various 	*)
(* records reference each other so much, we have to put them all here.	*)

vectorp = ↑vector;
transp = ↑trans;
strngp = ↑strng;
eventp = ↑event;
framep = ↑frame;
statementp = ↑statement;
varidefp = ↑varidef;
nodep = ↑node;
identp = ↑ident;
tokenp = ↑token;
reswordp = ↑resword;
pdbp = ↑integer;
envheaderp = ↑integer;
enventryp = ↑integer;
environp = ↑integer;
cmoncbp = ↑cmoncb;
messagep = ↑integer;
linerecp = ↑linerec;


(* datatype definitions *)

datatypes = (pconstype, varitype, svaltype, vectype, rottype, transtype,
	     frametype, eventtype, strngtype, labeltype, proctype, arraytype,
	     reftype, valtype, cmontype, nulltype, undeftype,
	     dimensiontype, mactype, macargtype, freevartype);

scalar = real;
vector = record  refcnt: integer; val: array [1..3] of real end;
trans = record  refcnt: integer; val: array [1..3,1..4] of real end;

cstring = packed array [1..10] of ascii;
c4str = packed array [1..4] of ascii;
c5str = packed array [1..5] of ascii;
c20str = packed array [1..20] of ascii;
linestr = packed array [1..130] of ascii;

strng = record
	  next: strngp;
	  ch: cstring;
	end;

event = record
	  next: eventp;		(* all events are on one big list *)
	  count: integer;
	  waitlist: pdbp;
	end;

frame = record
	  vari: varidefp;	(* back pointer to variable name & info *)
	  calcs: nodep;		(* affixment info *)
	  case ftype: boolean of	(* frame = true, device = false *)
  true:	    (valid: integer; val, fdepr: transp; dcntr: integer; dev: framep);
  false:    (mech: integer; case sdev: boolean of
		true: (sdest: real); false: (tdest,appr,depr: transp));
		(* sdev = true for scalar devices, false for frames *)
	end;


(* statement definitions *)

stmntypes = (progtype, blocktype, coblocktype, endtype, coendtype,
		fortype, iftype, whiletype, untiltype, casetype,
		calltype, returntype,
		printtype, prompttype, pausetype, aborttype, assigntype,
		signaltype, waittype, enabletype, disabletype, cmtype,
		affixtype, unfixtype,
		movetype,jtmovetype,operatetype,opentype,closetype,centertype,
		floattype, stoptype, retrytype,
		requiretype, definetype, macrotype, commenttype, dimdeftype,
		setbasetype, wristtype, saytype, declaretype, emptytype,
		evaltype, armmagictype);
		(* more??? *)

statement = packed record
		next, last: statementp;
		stlab: varidefp;
		exprs: nodep;	(* any expressions used by this statement *)
		nlines: integer;
		bpt,bad: boolean;
		case stype: stmntypes of

    progtype:	    (pcode: statementp; errors: integer);
    blocktype,
    declaretype,
    endtype,
    coendtype:	    (bcode, bparent: statementp; blkid: identp;
			level, numvars: 0..255; variables: varidefp);
    coblocktype:    (threads: nodep; nthreads: integer; cblkid: identp);
    fortype:	    (forvar, initial, step, final: nodep; fbody: statementp);
    whiletype,
    untiltype:	    (cond: nodep; body: statementp);
    casetype:	    (index: nodep; range, ncases: integer; caselist: nodep);
    iftype:	    (icond: nodep; thn, els: statementp);
    pausetype:	    (ptime: nodep);
    prompttype,
    printtype,
    aborttype,
    saytype:	    (plist: nodep; debugLev: integer);
    returntype:	    (retval, rproc: nodep);
    evaltype,
    calltype,
    assigntype:     (what, aval: nodep);
    affixtype,
    unfixtype:	    (frame1, frame2, byvar, atexp: nodep; rigid: boolean);
    signaltype,
    waittype:	    (event: nodep);
    movetype,
    jtmovetype,
    operatetype,
    opentype,
    closetype,
    centertype,
    floattype,
    setbasetype,
    stoptype:	    (cf, clauses: nodep);
    retrytype:	    (rcode, rparent: statementp; olevel: integer);
    wristtype:	    (arm, ff, fvec, tvec: nodep; csys: boolean);
    cmtype:	    (oncond: nodep; conclusion: statementp;
			deferCm, exprCm: boolean; cdef: varidefp);
    enabletype,
    disabletype:    (cmonlab: varidefp);
    requiretype:    (rfil: boolean; rfils: strngp; rfilen: integer);
    definetype:	    (macname,mpars: varidefp; macdef: tokenp);
    commenttype:    (len: integer; str: strngp; cbody: statementp);
    dimdeftype:	    (dimname: varidefp; dimexpr: nodep);
    armmagictype:   (cmdnum,dev,iargs,oargs: nodep);
		end;



(* auxiliary definitions: variable, etc. *)

varidef = packed record
	    next,dnext: varidefp;
	    name: identp;
	    level: 0..255;	(* environment level *)
	    offset: 0..255;	(* environment offset *)
	    dtype: varidefp;	(* to hold the dimension info *)
	    tbits: 0..15;  (* special type bits: array = 1, proc = 2, ref = 4 & ? *)
	    dbits: 0..15;	(* for use by debugger/interpreter *)
	    case vtype: datatypes of
  arraytype:  (a: nodep);
  proctype:   (p: nodep);
  labeltype,
  cmontype:   (s: statementp);
  mactype:    (mdef: statementp);
  macargtype: (marg: tokenp);
  pconstype:  (c: nodep);
  dimensiontype: (dim: nodep);
	  end;



(* definition of the ubiquitous NODE record *)

nodetypes = (exprnode, leafnode, listnode, clistnode, colistnode, forvalnode,
		deprnode, viaptnode, apprnode, destnode, byptnode, durnode,
		sfacnode, wobblenode, swtnode, nullingnode, wristnode, cwnode,
		arrivalnode, departingnode,
		ffnode, forcenode, stiffnode, gathernode, cmonnode, errornode,
		calcnode, arraydefnode, bnddefnode, bndvalnode,
		waitlistnode, procdefnode, tlistnode, dimnode, commentnode,
		linearnode, elbownode, shouldernode, flipnode, wrtnode,
		loadnode,velocitynode);

exprtypes =  (	svalop,					(* scalar operators *)
		sltop, sleop, seqop, sgeop, sgtop, sneop,	(* relations *)
		notop, orop, xorop, andop, eqvop,		(* logical *)
		saddop, ssubop, smulop, sdivop, snegop, sabsop, (* scalar ops *)
		sexpop, maxop, minop, intop, idivop, modop,
		sqrtop, logop, expop, timeop,			(* functions *)
		sinop, cosop, tanop, asinop, acosop, atan2op,	(* trig *)
		vdotop, vmagnop, tmagnop,
		vecop,					(* vector operators *)
		vmakeop, unitvop, vaddop, vsubop, crossvop, vnegop,
		svmulop, vsmulop, vsdivop, tvmulop, wrtop,
		tposop, taxisop,
		transop,				(* trans operators *)
		tmakeop, torientop, ttmulop, tvaddop, tvsubop, tinvrtop,
		vsaxwrop, constrop, ftofop, deproachop, fmakeop, vmkfrcop,
		ioop,					(* i/o operators *)
		queryop, inscalarop,
		specop,					(* special operators *)
		arefop, callop, grinchop, macroop, vmop, adcop, dacop, jointop,
		badop,
		addop, subop, negop, mulop, divop, absop); (* for parsing *)

leaftypes = pconstype..strngtype;

reltypes = sltop..sgtop;
forcetypes = (force,absforce,torque,abstorque,angvelocity);

node = record
	next: nodep;
	case ntype: nodetypes of
    exprnode:	(op: exprtypes; arg1, arg2, arg3: nodep; elength: integer);
    leafnode:	(case ltype: leaftypes of
	varitype:  (vari: varidefp; vid: identp);
	pconstype: (cname: varidefp; pcval: nodep);
	svaltype:  (s: scalar; wid: integer);
	vectype:   (v: vectorp);
	transtype: (t: transp);
	strngtype: (length: integer; str: strngp) ); (* also used by commentnodes *)
    listnode:	(lval: nodep);
    clistnode:	(cval: integer; stmnt: statementp; clast: nodep);
    colistnode:	(prev: nodep; cstmnt: statementp);
    forvalnode:	(fvar: enventryp; fstep: scalar);
    arrivalnode:(evar: varidefp);
    wrtnode,
    deprnode,
    apprnode,
    destnode:	(loc: nodep; code: statementp);
    byptnode,
    viaptnode:	(vlist: boolean; via,vclauses: nodep; vcode: statementp);
    durnode:	(durrel: reltypes; durval: nodep);
    velocitynode,
    sfacnode,
    wobblenode,
    swtnode:	(clval: nodep);
    nullingnode,			(* true = nonulling *)
    wristnode,				(*	= don't zero force wrist *)
    cwnode,				(*	= counter_clockwise *)
    elbownode,				(*	= elbow up *)
    shouldernode,			(*	= right shoulder *)
    flipnode,				(*	= don't flip wrist *)
    linearnode:	(notp: boolean);	(*	= linear motion *)
    ffnode:	(ff,cf: nodep; csys, pdef: boolean); (* true = world, false = hand *)
    loadnode:	(loadval,loadvec: nodep; lcsys: boolean); (* lcsys = csys above *)
    forcenode:	(ftype: forcetypes; frel: reltypes; fval, fvec, fframe: nodep);
    stiffnode:	(fv, mv, cocff: nodep);
    gathernode:	(gbits: integer);
    cmonnode:	(cmon: statementp; errhandlerp: boolean);
    errornode:	(eexpr: nodep);
    calcnode: 	(rigid, frame1: boolean; other: framep; case tvarp: boolean of 
		    false: (tval: transp); true: (tvar: enventryp) );
    arraydefnode: (numdims: 1..10; bounds: nodep; combnds: boolean);
    bnddefnode:	(lower, upper: nodep);
    bndvalnode:	(lb, ub, mult: integer);
    waitlistnode: (who: pdbp; when: integer);
    procdefnode:(ptype: datatypes; level: 0..255;
		    pname, paramlist: varidefp; body: statementp);
    tlistnode:	(tok: tokenp);
    dimnode:	(time, distance, angle, dforce: integer);
	end;



(* records for parser: ident, token, resword *)

ident = record
	    next: identp;
	    length: integer;
	    name: strngp;
	    predefined: varidefp;
	  end;


tokentypes = (reswdtype, identtype, constype, comnttype, delimtype, labeldeftype,
		macpartype);

constypes = svaltype..strngtype;

reswdtypes = (stmnttype, filtype, clsetype, decltype, optype, edittype);

filtypes = (abouttype,alongtype,attype,bytype,defertype,dotype,elsetype,
		errmodestype,fromtype,handtype,intype,nonrigidlytype,rigidlytype,
		sourcefiletype,steptype,thentype,totype,untltype,viatype,
		withtype,worldtype,zeroedtype,oftype,wheretype,nowaittype,
		ontype,offtype,ppsizetype,collecttype,alltype,lextype,
		notype,righttype,lefttype,uptype,downtype,motiontype);

clsetypes = (approachtype,arrivaltype,departuretype,departingtype,durationtype,
		errortype,forcetype,forceframetype,forcewristtype,gathertype,
		nildeproachtype,nullingtype,stiffnesstype,
		torquetype,velocitytype,wobbletype,
		cwtype,ccwtype,stopwaittimetype,angularvelocitytype,
		respecttype,elbowtype,shouldertype,fliptype,lineartype,
		jointspacetype,loadtype);

edittypes = (getcmd,savecmd,insertcmd,renamecmd,startcmd,gocmd,proceedcmd,
		stepcmd,sstepcmd,nstepcmd,gstepcmd,executecmd,setcmd,tracecmd,
		breakcmd,unbreakcmd,tbreakcmd,definecmd,markcmd,unmarkcmd,
		popcmd,atcmd,calibratecmd);

token = record
	  next: tokenp;
	  case ttype: tokentypes of
constype:   (cons: nodep);
comnttype:  (len: integer; str: strngp);
delimtype:  (ch: ascii);
reswdtype:  (case rtype: reswdtypes of
	stmnttype: (stmnt: stmntypes);
	filtype:   (filler: filtypes);
	clsetype:  (clause: clsetypes);
	decltype:  (decl: datatypes);
	optype:	   (op: exprtypes);
	edittype:  (ed: edittypes) );
identtype:  (id: identp);
labeldeftype: (lab: varidefp);
macpartype: (mpar: varidefp);
	end;


resword = record
	  next: reswordp;
	  length: integer;
	  name: strngp;
	  case rtype: reswdtypes of
	stmnttype:  (stmnt: stmntypes);
	filtype:    (filler: filtypes);
	clsetype:   (clause: clsetypes);
	decltype:   (decl: datatypes);
	optype:	    (op: exprtypes);
	edittype:  (ed: edittypes);
	  end;


cmoncb = record
	   running, enabled: boolean;		(* cmon's status *)
	   cmon: statementp;
	   pdb: pdbp;
	   evt: eventp;
	   fbits: integer;			(* bits for force sensing *)
	   oldcmon: cmoncbp;			(* for debugger *)
	 end;


(* print related records: *)

cursorp = record
	  cline,ind: integer;
	  case stmntp: boolean of
  true:    (st: statementp);
  false:   (nd: nodep);
	 end;

linerec = record
	next: linerecp;
	start,length: integer
       end;

listingarray = packed array [0..listinglength] of ascii;



(* global variables *)

var
	(* from EDIT *)
    listing: listingarray;  (* first 150 chars are used by expression editor *)
			    (* next 40 by header & trailer lines *)
{*} cursorStack: array [1..15] of cursorp;	{These are BIG records! }
    lbuf: array [1..160] of ascii;
    ppBuf: array [1..100] of ascii;
    lines: array [1..maxLines] of linerecp; (* what's on the screen + some *)
    ppLines: array [1..maxPPLines] of linerecp;	(* for page printer *)
    marks: array [1..20] of integer;
    reswords: array [0..26] of reswordp;
    idents: array [0..26] of identp;
    macrostack: array [1..10] of tokenp;
    curmacstack: array [1..10] of varidefp;
    screenheight,dispHeight: integer;
    ppBufp,oppBufp,ppOffset,ppSize,nmarks: integer;
    lbufp,cursor,ocur,cursorLine,fieldnum,lineNum,findLine,pcLine: integer;
    firstDline,topDline,botDline,firstLine,lastLine,curLine: integer;
    freeLines,oldLines: linerecp;
    sysVars: varidefp;
    dProg: statementp;
    curBlock, newDeclarations, findStmnt: statementp;
    macrodepth: integer;
    filedepth, errCount, sCursor: integer;
    curChar, maxChar, curFLine, curPage: integer;
    nodim, distancedim, timedim, angledim,
      forcedim, torquedim, veldim, angveldim: varidefp;
    fvstiffdim, mvstiffdim: nodep;
    pnode: nodep;
    smartTerminal: boolean; (* true = insert/delete, false = redraw line *)
    setUp,setExpr,setCursor,dontPrint,outFilep,collect,fParse,sParse,
      eofError,endOfLine,backup,expandmacros,flushcomments,checkDims,
      shownLine: boolean;
    curtoken: token;
    file1,file2,file3,file4,file5,outFile: atext;

    bpts: array [1..maxBpts] of statementp;	(* debugging crap *)
    tbpts: array [1..maxTBpts] of statementp;
    debugPdbs: array [0..10] of pdbp;
    nbpts,ntbpts,debugLevel: integer;
    eCurInt: pdbp;
    STLevel: integer;		(* set by GO *)
    singleThreadMode,tSingleThreadMode: boolean;

	(* from INTERP *)
    inputLine: array [1..20] of ascii;
    talk: text;			(* for using the speech synthesizer *)
    curInt, activeInts, readQueue, allPdbs: pdbp;
    sysEnv: envheaderp;
    clkQueue: nodep;
    allEvents: eventp;
    etime: integer;		(* used by eval *)
    curtime: integer; (* who knows where this will get updated - an ast? *)
    stime: integer;		(* used for clock queue on 10 *)
    msg: messagep;		(* for AL-ARM interaction *)
    inputp: integer;		(* current offset into inputLine array above *)
    resched, running, escapeI, iSingleThreadMode: boolean;
    msgp: boolean;		(* flag set if any messages pending *)
    inputReady: boolean;

(* various constant pointers *)
    xhat,yhat,zhat,nilvect: vectorp;
    niltrans: transp;
    gpark, rpark: transp;		(* arm park positions *)

(* various device & variable pointers *)
    speedfactor: enventryp;
    garm: framep;


(* External routines from elsewhere *)

	(* From ALLOC *)
procedure relToken(t: tokenp); 					external;			
procedure relNode(n: nodep); 					external;
procedure relStrng(n: strngp); 					external;
procedure relVector(n: vectorp); 				external;
procedure relTrans(n: transp); 					external;
procedure relIdent(n: identp); 					external;
procedure relVaridef(n: varidefp); 				external;
procedure relStatement(n: statementp); 				external;

	(* From INTERP - XX good luck Rick XX *)
	(* It's in eaux2a; FREE is in level 1 *)
	(* Maybe a case for CALLER... *)
{ procedure flushVar(oldvar: varidefp);				external; }

(* auxiliary routines: freStrng, freeVaridef, freeToken, freeNode, freeIds *)

procedure freeStatement(s: statementp); external;	{also FORWARD}

procedure freeNode(n: nodep); external;			{also FORWARD}

procedure freStrng(st: strngp); external;
procedure freStrng;
 var stp: strngp;
 begin
 while st <> nil do
    begin stp := st↑.next; relStrng(st); st := stp end;
 end;

procedure freeToken(t: tokenp); external;
procedure freeToken;
 var tp: tokenp;
 begin
 while t <> nil do
  begin
  with t↑ do
   begin
   if ttype = constype then
     if cons↑.ltype = svaltype then relNode(cons) else freeNode(cons)
    else if ttype = comnttype then freStrng(str);
   tp := next;
   end;
  relToken(t);
  t := tp
  end;
 end;

procedure freeVaridef(v: varidefp); external;
procedure freeVaridef;
 var vp: varidefp;
 begin
 while v <> nil do
  with v↑ do
   begin
   if tbits = 2 then freeNode(p)		(* procedure definition *)
    else if odd(tbits) then freeNode(a)		(* array definition *)
    else
     case vtype of
macargtype: freeToken(marg);
dimensiontype: relNode(dim);
otherwise {do nothing};
    end;
   vp := next;
   relVaridef(v);
   v := vp;
   end;
 end;

procedure freeNode (* n: nodep *);
 var b: boolean;
 begin
 b := true;
 if n = nil then b := false
  else
   with n↑ do
    case ntype of
exprnode: begin
	  freeNode(arg1);
	  freeNode(arg2);
	  freeNode(arg3);
	  end;
leafnode: case ltype of
  vectype:   if v↑.refcnt <= 1 then relVector(v)
	      else v↑.refcnt := v↑.refcnt - 1;
  transtype: if t↑.refcnt <= 1 then relTrans(t)
	      else t↑.refcnt := t↑.refcnt - 1;
  strngtype: if (length <> 2) or (str↑.ch[1] <> chr(15B)) or
		(str↑.ch[2] <> chr(12B)) then freStrng(str) else b := false;
  otherwise {do nothing};
	   end;
listnode: begin
	  freeNode(lval);
	  freeNode(next);
	  end;
clistnode:begin
	  freeStatement(stmnt);
	  freeNode(next);
	  end;
colistnode: begin
	  freeStatement(cstmnt);
	  freeNode(next);
	  end;
deprnode,
apprnode,
destnode: begin
	  freeNode(loc);
	  freeStatement(code);
	  freeNode(next);
	  end;
byptnode,
viaptnode:begin
	  freeNode(via);
	  freeNode(vclauses);
	  freeStatement(vcode);
	  freeNode(next);
	  end;
durnode:  begin
	  freeNode(durval);
	  freeNode(next);
	  end;
wrtnode,
velocitynode,
sfacnode,
wobblenode,
swtnode:  begin
	  freeNode(clval);
	  freeNode(next);
	  end;
gathernode,
nullingnode,
wristnode,
elbownode,
shouldernode,
flipnode,
linearnode,
cwnode:	  freeNode(next);
ffnode:	  begin
	  if pdef then relNode(ff)
	   else freeNode(ff);
	  freeNode(next);
	  end;
forcenode:begin
	  freeNode(fval);
	  freeNode(fvec);
	  freeNode(fframe);
	  freeNode(next);
	  end;
loadnode: begin
	  freeNode(loadval);
	  freeNode(loadvec);
	  freeNode(next);
	  end;
stiffnode:begin
	  freeNode(fv);
	  freeNode(mv);
	  freeNode(cocff);
	  freeNode(next);
	  end;
cmonnode: begin
	  freeStatement(cmon);
	  freeNode(next);
	  end;
errornode:begin
	  freeNode(eexpr);
	  end;
calcnode: if not tvarp then relTrans(tval);	(* should never see one but *)
arraydefnode: freeNode(bounds);
bnddefnode:begin
	  freeNode(lower);
	  freeNode(upper);
	  freeNode(next);
	  end;
procdefnode:begin
	  freeVaridef(paramlist);
	  relStatement(body↑.next);
	  freeStatement(body);
	  end;
tlistnode: freeToken(tok);
otherwise {do nothing};
    end;
 if b then relNode(n);
 end;


procedure freeIds; external;
procedure freeIds;
 var i: integer; id,idp,idn: identp; st,stp: strngp;
 begin
 for i := 1 to 26 do
  begin
  idp := nil;
  id := idents[i];
  while id <> nil do
   with id↑ do
    begin
    idn := next;
    if predefined = nil then
      begin				(* flush id now *)
      st := name;			(* done with string *)
      while st <> nil do
	 begin stp := st↑.next; relStrng(st); st := stp end;
      relIdent(id);			(* and ident *)
      end
     else
      begin
      if idp = nil then idents[i] := id else idp↑.next := id;
      idp := id;
      end;
    id := idn;
    end;
  if idp = nil then idents[i] := nil;
  end;
 end;

(* routine to free up a program once we're done with it: freeStatement *)

procedure freeStatement(* s: statementp *);
 var st,stp: statementp; n: nodep;

    procedure clrBpt(st: statementp);	(* copied from EAUX3B *)
     var i: integer; b: boolean;
     begin
     if st↑.bpt then                (* don't do anything if bpt not set *)
       begin
       b := true;
       for i := 1 to nbpts do
	if b then b := bpts[i] <> st        (* first find statement in list *)
	 else bpts[i-1] := bpts[i];         (* then compact the list *)
       if not b then
	 begin
	 st↑.bpt := false;                  (* clear it only if we set it *)
	 bpts[nbpts] := nil;
	 nbpts := nbpts - 1;
	 end;
      (* else wonder how the bpt got set? *)
       end;
     end;

 begin
 if s <> nil then
   begin
   with s↑ do
    begin
    if bpt then clrBpt(s);		(* keep the debugger tables legit *)
    case stype of
progtype:	begin
		freeStatement(pcode↑.next);
		freeStatement(pcode);
		freeIds;
		end;
blocktype:	begin
		if blkid <> nil then
		  begin
		  freStrng(blkid↑.name);
		  relIdent(blkid);
		  end;
		st := bcode;
		while st <> nil do
		 begin
		 stp := st↑.next;
		 freeStatement(st);
		 st := stp;
		 end;
		freeVaridef(variables);
		end;
endtype,
coendtype:	if blkid <> nil then
		  begin
		  freStrng(blkid↑.name);
		  relIdent(blkid);
		  end;
coblocktype:	begin
		if cblkid <> nil then
		  begin
		  freStrng(cblkid↑.name);
		  relIdent(cblkid);
		  end;
		if threads <> nil then freeStatement(threads↑.cstmnt↑.next);
		freeNode(threads);
		end;
fortype:	begin
		freeNode(forvar);
		freeNode(initial);
		freeNode(step);
		freeNode(final);
		if fbody <> nil then freeStatement(fbody↑.next);
		freeStatement(fbody);
		end;
whiletype,
untiltype:	begin
		freeNode(cond);
		if body <> nil then freeStatement(body↑.next);
		freeStatement(body);
		end;
casetype:	begin
		freeNode(index);
		n := caselist;
		while n <> nil do
		 if n↑.stmnt = nil then n := n↑.next
		  else begin freeStatement(n↑.stmnt↑.next); n := nil end;
		freeNode(caselist);
		end;
iftype:		begin
		freeNode(icond);
		if thn <> nil then freeStatement(thn↑.next);
		freeStatement(thn);
		freeStatement(els);
		end;
pausetype:	freeNode(ptime);
prompttype,
printtype,
aborttype,
saytype:	freeNode(plist);
returntype:	freeNode(retval);
calltype:	freeNode(what);
assigntype:	begin
		freeNode(what);
		freeNode(aval);
		end;
affixtype,
unfixtype:	begin
		freeNode(frame1);
		freeNode(frame2);
		if stype = affixtype then
		  begin
		  freeNode(byvar);
		  freeNode(atexp);
		  end;
		end;
signaltype,
waittype:	freeNode(event);
movetype,
jtmovetype,
operatetype,
opentype,
closetype,
centertype:	begin
		freeNode(cf);
		freeNode(clauses);
		end;
setbasetype,
stoptype:	freeNode(cf);
cmtype:		begin
		if (not exprCm) and (oncond↑.ntype = leafnode) then
(*		  if oncond↑.vari↑.name = nil then flushVar(oncond↑.vari);
		flushVar(cdef);
*)
		freeNode(oncond);
		freeStatement(conclusion↑.next);
		freeStatement(conclusion);
		end;
requiretype:	freStrng(rfils);
definetype:	begin
		freeVaridef(mpars);
		freeToken(macdef);
		end;
commenttype:	begin
		freStrng(str);
		freeStatement(cbody);
		end;
dimdeftype:	freeNode(dimexpr);
wristtype:	begin
		freeNode(arm);
		freeNode(ff);
		freeNode(fvec);
		freeNode(tvec);
		end;
armmagictype:	begin
		freeNode(cmdnum);
		freeNode(dev);
		freeNode(iargs);
		freeNode(oargs);
		end;
otherwise	{do nothing - shouldn't happen};
     end;
    end;
   relStatement(s);
   end;
 end;